eCircuit  Center

About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION |
SPICE
Commands | SPICE
Demos and Downloads
About Us | Contact Us | Home

Current-to-Voltage
Amplifier

CIRCUIT

OPITOV.CIR
Download
the SPICE file

You may have noticed that most circuits work on a convenient principle:
Voltage In, Voltage Out. But, what about the large class of sensors, such
as a photodiode, that produce a current? Photodiodes may be called into
action for applications such as precision light meters or high-speed
fiber-optic receivers. If you need to amplify the signal from this type of
sensor, you must first convert this current to a useful voltage.

TRANSIMPEDANCE AMPLIFIER

The op amp current-to-voltage converter (transimpedance amplifier) is a
fairly simple circuit. Two key principles clarify operation.

1. Because no current flows into the op amp itself, the current IS
has nowhere to go but through the resistor RF.

2. One leg of RF is held at ground potential (0V). Why? Remember the
main job of the op amp is to adjust the output such that the
inverting input equals the non-inverting input. And, because the
non-inverting input is at ground (0V), the inverting input - along with
RF - will be held at 0V.

What does it all mean? The output Vo can be described simply as the
voltage across the resistor VRF.

Vo = VRF = -IS x RF

CIRCUIT ANALYSIS
The current source IS delivers a 10 uA pulse (20 us
wide) to the transimpedance amp. The output voltage V(2) should show the
same pulse scaled by RF and inverted. Run a simulation of
OPITOV.CIR. Plot the Transient Response of input current I(IS) and
output voltage V(2). To get a better view of the input current, you may
need to display it in a separate plot window.

HANDS-ON DESIGN
Suppose you needed a larger output voltage given the
same 10 uA source? Pick a higher output voltage level and calculate a new
RF. (Example: For a 2V output pulse, choose RF = 2V / 10 uA = 200k.) Test
drive your circuit and check the output swing.

SENSOR RESISTANCE

CIRCUIT INSIGHT
Resistor RS represents the sensors source impedance.
Insert RS across IS by removing the * at the
beginning of the RS statement. Run a simulation. Did the output change?
Increase or decrease RS by a factor of 10 or so. Why doesn't the output
change? The op amp creates a fairly low impedance at the negative input by
forcing it near 0V. As a result, most of IS will flow into this low
impedance; not into the relatively higher resistance of RS.

WARNING - INSTABILITY AHEAD

If you said that the easy application of a transimpedance amp is too
good to be true - you'd be right! Optimizing current-to-voltage amplifiers
can be one of the most challenging aspects of op amp design. Why? The main
culprit is the sensor's own capacitance CS.

Capacitance CS brings two ill effects into your circuit.

1. It effectively places a short circuit across IS at high
frequencies, limiting the circuit's bandwidth.

2. CS tends to make circuit unstable. How so? Notice as the
signal runs along the feedback path from output to input, RF and CS create
a low-pass filter. And filters of the low-pass kind contribute
negative phase to the feedback loop, making the circuit less
stable. (See Op
Amp Feedback Analysis.) Instability, rears its ugly head in your
circuit as overshoot, ringing or even oscillations.

CIRCUIT INSIGHT
Insert CS=100pF across IS by removing the * at the beginning of the CS statement (also make
values RS=500k and RF=100k). Run a simulation and plot the Transient
Response of the output V(2). What happened to the output voltage? How
much overshoot and ringing does CS cause?

Now, let's see how CS puts a bump in an otherwise flat frequency
response. Plot the AC Response of the output VM(2). How big is the
peak in the response versus frequency?

RESTORING STABILITY

Restoring stability requires counteracting the undesirable
low-pass filter RF and CS in the feedback path from output to
input. You can do this with a high-pass filter in the same feedback
path. Just add capacitor CF. High-pass filter, CF and RS, adds positive
phase to the loop pushing the circuit toward stability. But, as you know,
circuit design is an arena of compromise. And typically, the first
casualty of stability is bandwidth.

HANDS-ON DESIGN
Place CF=2PF across RF by removing the * at the beginning of the CF statement. Run a
simulation. Check out the Transient Response of output V(2). How
much of the overshoot and ringing have been reduced? Increase CF until the
overshoot and ringing are gone. But as you do this, notice what's
happening to the rise time.

Take a look at the AC Response VM(2). Yes, the peak is being
reduced, but, so is the overall bandwidth! That's because CF and RF create
a low-pass filter in the forward signal gain path from IS to
Vo.

Tuning your circuit for optimum response can be a two step process:

1. Increase CF until the overshoot and ringing are acceptable for
your application.

2. Check the rise time. If it meets your requirements, you're done.
If its too slow, pick a faster op amp and repeat steps 1 and
2.

SPICE FILE

Download
the file or copy this netlist into a text file with the *.cir
extention.

OPITOV.CIR - CURRENT-TO-VOLTAGE CONVERTER (TRANSIMPEDANCE AMP)
*
* SENSOR
IS 0 1 AC 1 PWL(0US 0UA 1US 10UA 20US 10UA 21US 0 40US 0)
*RS 1 0 500K
*CS 1 0 100PF
*
* TRANSIMPEDANCE AMPLIFIER
RF 1 2 100K
*CF 1 2 2PF
XOP1 0 1 2 OPAMP1
*
* OPAMP MACRO MODEL, SINGLE-POLE
* connections: non-inverting input
* | inverting input
* | | output
* | | |
.SUBCKT OPAMP1 1 2 6
* INPUT IMPEDANCE
RIN 1 2 10MEG
* gain bandwidth product = DCGAIN x POLE1 = 10MHZ
* DCGAIN=100K AND POLE1=100HZ
EGAIN 3 0 1 2 100K
R1 3 4 1K
C1 4 0 1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER 5 0 4 0 1
ROUT 5 6 10
.ENDS
*
* ANALYSIS
.TRAN 0.2US 40US
.AC DEC 10 100 10MEG
* VIEW RESULTS
.PRINT TRAN V(2)
.PRINT AC VM(2)
.PROBE
.END

top

© 2002 eCircuit
Center