*
* ..File: xc2ph2p.f 
*
*
* ..Calculation of the O(a_em a_s) MS(bar) photon coefficient function 
*    for F2 using a compact parametrization involving only logarithms.
*    Scales: mu_r = mu_f = Q. The expansion parameters are taken as
*    a_em = alpha_em/(4 pi),  a_s = alpha_s/(4 pi).
*
* ..The charge prefactor  delta_f = 3 N_f <e^4>  has to be supplemented 
*    by the calling routines.
*
*  ..The distributions (in the mathematical sense) are given as in eq.
*    (B.26) of Floratos, Kounnas, Lacaze: Nucl. Phys. B192 (1981) 417.
*    The name-endings A, B, and C of the functions below correspond to 
*    the kernel superscripts [2], [3], and [1] in that equation.
*
*  ..The relative accuracy of the coefficient functions, as well as of
*    the convolution results, amounts to a few thousandth.
*
*  ..Reference: S. Moch, J. Vermaseren and A. Vogt, 
*               hep-ph/0110331 = Nucl. Phys. B621 (2002) 413
*
* 
* =====================================================================
*
*
* ..This is the regular piece, connected by TR->3 to the CF*TR part of 
*    C2G2A in c2sg2p.f. Ten numerical coefficients are fitted, the ones 
*    of ln^3(1-y) and ln^2(1-y) are exact up to truncation.
*
       FUNCTION C2P2A (Y, NF)
       IMPLICIT REAL*8 (A-Z)
       INTEGER NF
*
       DL  = LOG (Y)
       DL1 = LOG (1.-Y)
*
       C2P2A = (- 13.86 * DL**3 - 27.74 * DL**2 - 67.33 * DL
     1          - 1576. - 2727.* Y + 3823.* Y**2 
     2          + (26.67 - 317.5 * (1.-Y)) * DL1**3 - 72.00 * DL1**2  
     3          + (- 1287./ Y + 906.8) * DL1 + 1598.* DL * DL1 ) /3.D0
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
*
* ..This is the 'local' photon piece, cf. the discussion of C2G2C. 
*    The constant is fixed from the lowest even-integer moments. 
*
       FUNCTION C2P2C (Y, NF)
       IMPLICIT REAL*8 (A-Z)
       INTEGER NF
*
       C2P2C = - 0.59 / 3.D0
*
       RETURN
       END
*
* =================================================================av==
