#-
*
*   Example of the use of sumnmii (Appendix C), the tables for values at
*   infinity and a check of one of the relations coming from the theorem
*   in section 5 of the paper.
*
#define SIZE "7"
*
*   SIZE tells how far we have to read the tables with the values at
*   infinity. Be careful: for 7 or more it reads the whole tables which
*   is more than 660 Kbytes. This may take a few seconds.
*
#include nndecl.h
.global
#+
*
*   First a direct application of the theorem at weight 7.
*   We have the series in the first line.
*   Writing the outermost sum of each of them gives a square grid over
*   which to sum.
*   In the second term we have a triangular grid in which one sum
*   has been done (to give the S-function with the inf-j1 argument)
*   According to the theorem these terms should be equal when inf -> infinity.
*
L   F = S(R(-1,2,1),inf)*S(R(1,-2),inf);
        -sum1(j1,1,inf)*S1(R(-1,2,1),inf-j1)*S1(R(-2),j1)/j1
*
*   The sum is worked out with the procedure sumnmii(i)
*   The parameter in sumnmii indicates the index of j. If the parameter
*   is left blank one would consider sum(j,1,...) etc
*
#call sumnmii(1)
*
*   Print only in file in a rather readable format.
*
Print +f +s;
.sort
*
*   Now load the tables to the proper size.
*
#call tables(`SIZE')
*
*   Conversion to the notation of equation 8.
*
id  S(R(?a),inf) = SS(?a);
repeat id SS(?a,n?{2,...,{`MAXWEIGHT'}},?b) = SS(?a,0,n-1,?b);
repeat id SS(?a,n?{<-2>,...,<-`MAXWEIGHT'>},?b) = SS(?a,0,n+1,?b);
*
*   And show the result
*
Print +f +s;
.sort
*
*   And now we force the substitution.
*   Note: a table works much faster than 1458 id statements.
*
#do k = 1,`SIZE'
id  SS(n1?,...,n`k'?) = Stab`k'(n1,...,n`k');
#enddo
*
*   If all is OK, the answer should be zero off course.
*
Print +f +s;
.end